全バージョン共通

Windows 10をクリーンインストールする際に回復パーティションを移動させると同時にデータパーティションを作成する方法

  • コピーしました

Microsoftが推奨するパーティション配置に変更したうえで、ユーザーデータ用のパーティションを分ける方法について説明します。

改訂版について

使いやすくしたスクリプトについて説明した改訂版を記事にしましたので、こちらを参照願います。

 

回復パーティションの問題

Windows 10をクリーンインストールするとこのような順番でパーティションが確保されてしまいます。

回復システム予約Windows

 

これに対してMicrosoftが推奨するパーティション配置はこのようなものです。

システム予約Windows回復

 

この配置にはそれなりの意味があり、この配置に変更する方法についてはクリーンインストールする前にひと工夫する方法として説明しました。

 

ユーザーデータパーティション

前回の記事ではユーザーデータパーティションを分ける場合については、混乱を避けるため詳しく言及しませんでした。

しかし、Windowsの不具合の影響を受けないように、ユーザーデータパーティションは分けた方が良いのです。

例えば、NTFSのファイルシステムが壊れた場合、影響はドライブ全体に及びますが、パーティションを分けることでユーザーデータへの影響を抑えることができます。

 

ここでは、回復パーティションをドライブの最後に移動させた上でユーザーデータパーティションも分割する方法について説明します。

 

前提としてこのようなパーティション配置とします。

システム予約Windowsデータ回復

 

120GB程度のストレージを想定してWindowsパーティションを80GB、残りをユーザーデータパーティションとします。

ここでWindowsパーティションとユーザーデータパーティションのどちらを優先するかという問題があります。

Windowsパーティションは容量が不足した場合に不要なファイルを消して増やすことが難しいので、Windowsパーティションを優先して予め多めに確保しておくのが得策です。

 

なお、やっていることを理解すればサイズの変更やパーティションの数を増やすことは比較的簡単でしょう。

 

マニュアルでの分割

簡単な方法は前回と同様の手順で進め、この画面で一度Windowsパーティションを削除して再度Windowsパーティションとデータパーティションを確保する方法です。

Windows10-Prepare-Data-Partition-00

クリーンインストールの頻度が低いならこの方法で十分でしょう。

 

「Windows」パーティションが選択されていることを確認して「削除」をクリックします。

Windows10-Prepare-Data-Partition-01

確認のダイアログが表示されるので「OK」をクリックして削除します。

Windows10-Prepare-Data-Partition-02

削除した領域を選択して「新規」をクリックします。

Windows10-Prepare-Data-Partition-03

「Windows」パーティションは80GBとしますのでMBに換算すると、

  • 80(GB) × 1024(MB) = 81920(MB)

ですので、サイズに「81920」を指定して「適用」をクリックします。

Windows10-Prepare-Data-Partition-04

80GBのパーティションが作成されます。

この方法ではボリュームラベルを付けられないため順番で用途を把握します。

Windows10-Prepare-Data-Partition-05

ひとつ下の割り当てられていない領域を選択し「新規」をクリックします。

Windows10-Prepare-Data-Partition-06

残りはすべて「ユーザーデータ」パーティションとしますのでサイズは表示されたままとし「適用」をクリックします。

Windows10-Prepare-Data-Partition-07

「ユーザーデータ」パーティションが作成されます。

「ユーザーデータ」パーティションが選択された状態で「フォーマット」をクリックします。

Windows10-Prepare-Data-Partition-08

確認のダイアログが表示されるので「OK」をクリックしてフォーマットします。

「Windows」パーティションは自動でフォーマットされますが、「ユーザーデータ」パーティションはフォーマットしないとWindows 10のインストール段階でドライブ文字が割り当てられないので注意してください。

Windows10-Prepare-Data-Partition-09

「Windows」パーティションとなるパーティションを選択して「次へ」をクリックします。

Windows10-Prepare-Data-Partition-10

Windows 10のインストールが始まりますので、インストールを完了させます。

Windows10-Prepare-Data-Partition-11

Windows 10のインストールが完了したら「ディスクの管理」を起動してパーティションを確認すると、「ユーザーデータ」パーティションとしてDドライブが作成されていることを確認できます。

Windows10-Prepare-Data-Partition-12

 

スクリプトを変更

もちろん、スクリプトを変更することで同じことはできます。

毎回サイズを計算するのが面倒ならスクリプトを使った方が良いでしょう。

こちらのファイルをダウンロードしてください。

 

ユーザーデータパーティションを作成する「CreatePartitions-UEFI.txt」が含まれています。

「Windows」パーティションのサイズを変更する場合は黄色の部分を変更します。


rem =====================================================
rem =   ファイル名:CreatePartitions-UEFI.txt           =
rem =                                                   =
rem =   ユーザーデータパーティション分割版              =
rem =                                                   =
rem =   2017/08/22      初版                            =
rem =====================================================
rem =   このスクリプトは DISKPARTコマンドを使って       =
rem =   5つのパーティションを作成します。              =
rem =   UEFI対応のパソコン専用です。                    =
rem =                                                   =
rem =   1番目のドライブすべてを消してパーティションを  =
rem =   切り直しますので使用には注意してください。      =
rem =                                                   =
rem =   ドライブすべてを使ってパーティションを          =
rem =   割り当てるので、必要な場合は各パーティションの  =
rem =   サイズを調整してください。                      =
rem =====================================================
select disk 0
clean
convert gpt
rem =====================================================
rem =   1.システムパーティション                        =
rem =====================================================
rem =   注意:  4KBセクターのドライブの場合は           =
rem =           size=260 に変更してください。           =
rem =====================================================
create partition efi size=100
format quick fs=fat32 label="System"
assign letter="S"
rem =====================================================
rem =   2.マイクロソフト予約パーティション (MSR)        =
rem =====================================================
create partition msr size=16
rem =====================================================
rem =   3.Windowsパーティション                         =
rem =====================================================
rem =   注意:  サイズはMB単位で指定します。            =
rem =           ここでは80GBとしています。              =
rem =           1GB以上を指定する場合は                 =
rem =           1GB=1024MBとしてサイズを計算します。   =
rem =====================================================
create partition primary size=81920
format quick fs=ntfs label="Windows"
assign letter="W"
rem =====================================================
rem =   4.User Dataパーティション                       =
rem =====================================================
rem =   4-1.User Dataパーティションの作成               =
rem =====================================================
create partition primary
rem =====================================================
rem =   4-2.回復パーティション用のスペースを作成        =
rem =====================================================
rem =   注意:  回復パーティションのサイズは            =
rem =           MB単位で指定します。                    =
rem =           既定は450MBですが1GBとしています。      =
rem =           1GB以上を指定する場合は                 =
rem =           1GB=1024MBとしてサイズを計算します。   =
rem =====================================================
shrink minimum=1024
format quick fs=ntfs label="User Data"
assign letter="U"
rem =====================================================
rem =   5.回復パーティション                            =
rem =====================================================
create partition primary
format quick fs=ntfs label="Windows RE tools"
assign letter="R"
set id="de94bba4-06d1-4d40-a16a-bfd50179d6ac"
gpt attributes=0x8000000000000001
rem =====================================================
rem =   作成されたパーティションを表示                  =
rem =====================================================
list partition
exit

 

あとは、前回の記事の「CreatePartitions-UEFI.txt」と置き換えて実行するだけです。

Windows10-Prepare-Data-Partition-21

Windows10-Prepare-Data-Partition-22

Windows10-Prepare-Data-Partition-23

今回のスクリプトではこのように5個のパーティションが作成されます。

Windows10-Prepare-Data-Partition-25

マニュアルでの分割と違いボリュームラベルを付けていますので、「Windows」と表示されているパーティションが選択されていることを確認してインストールを進めます。

Windows10-Prepare-Data-Partition-27

Windows10-Prepare-Data-Partition-28

Windows 10のインストールが完了したら「ディスクの管理」を起動してみると正しくパーティションが作成されていることが確認できます。

マニュアルでの分割と違いボリュームラベルが予め設定されていますが、ボリュームラベルはいつでもドライブのプロパティから変更できますのでどちらの方法でも結果に違いはありません。

Windows10-Prepare-Data-Partition-29

 

まとめ

自動応答ファイルを作成することでWindows 10のインストール自体を自動化することはできますが、どのパソコンでも共通で使えるものを作るのは難しいものがあります。

しかし、パーティション構成など比較的共通点が多いものは簡単なスクリプトで手間を省き間違いを防ぐことができます。

利用環境に合うようなら試してみてください。

なお、テストはしていますが動作がおかしい点や改善点などがありましたらコメントを頂けると助かります。

  • コピーしました

コメントフォーム

御不明な点や御質問、御意見についてはコメントを頂けると幸いです。
メールアドレスは非公開となり、こちらからメールで御連絡を差し上げることはございません。
[*] が付いている項目は必須となりますので必ず入力を御願い致します。


コメントはサイト管理者が承認するまで表示されませんので御了承願います。
このサイトは日本国外からのコメントは受け付けておりません。
This site does not accept comments from outside Japan.



This site is protected by reCAPTCHA and the Google Privacy Policy and Terms of Service apply.

Windows 10 ナビゲーター
おすすめの記事
サイト内検索
人気の投稿
最近のコメント
アーカイブ
サイバーリンク PowerDVD 18 無料イラスト素材【イラストAC】
カテゴリー